//JOBNAME  JOB (ACCT),NAME,CLASS=A,MSGCLASS=A,MSGLEVEL=(1,1)
//*********************************************************************
//ASMCG    PROC AOPT=,APARM=,LOPT=,
//             MAC1='SYS1.MACLIB',
//             MAC2='SYS1.MACLIB',
//             MAC3='SYS1.MODGEN'
//ASM      EXEC PGM=ASMA90,
//         PARM=('OBJ,NODECK,LC(32767),XREF(SHORT),TERM,RLD,ASA,&AOPT',
//             'US(MAP,WARN(11)),SYSPARM(&APARM)')
//SYSPRINT DD SYSOUT=*
//SYSTERM  DD SYSOUT=*
//SYSLIB   DD DISP=SHR,DSN=&MAC1
//         DD DISP=SHR,DSN=&MAC2
//         DD DISP=SHR,DSN=&MAC3
//SYSUT1   DD UNIT=SYSALLDA,SPACE=(TRK,(80,20))
//SYSLIN   DD DISP=(,PASS),UNIT=SYSALLDA,SPACE=(TRK,(30,15),RLSE),
//            DCB=(RECFM=FB,BLKSIZE=0,LRECL=80)
//GO       EXEC PGM=LOADER,COND=(5,LT,ASM),
//         PARM=('LIST,LET,MAP,XREF,&LOPT')
//SYSLOUT  DD DUMMY
//SYSLIN   DD DSN=*.ASM.SYSLIN,DISP=(OLD,DELETE)
//         PEND
//*********************************************************************
//STEP1    EXEC ASMCG
//ASM.SYSIN DD *
&MODNAME SETC  'MYASMPGM'
*=====================================================================*
*        MVS STANDARD HOUSE KEEPING PROCEDURE                         *
*=====================================================================*
*                                  *----------------------------------*
*                                  *  ENTRY PROCESSING                *
*                                  *----------------------------------*
&MODNAME CSECT ,                        DEFINE CONTROL SECTION
&MODNAME AMODE 31                       DEFINE DEFAULT AMODE=31
&MODNAME RMODE 24                       DEFINE DEFAULT RMODE=24
         USING *,12                     DEFINE BASE REGISTER
         SAVE  (14,12),,*               SAVE CALLER REGISTERS
         LA    12,0(,15)                GR12 --> OUR 1ST BASE ADDRESS
         LR    15,13                    SAVE CALLER SAVEAREA
         CNOP  0,4                      INSURE FULL WORD BOUNDARY
         BAS   13,*+4+72                AROUND OUR SAVEAREA
         DC    18F'-1'                  OUR GPR SAVEAREA
         ST    15,4(,13)                SAVE CALLER SAVEAREA POINTER
         ST    13,8(,15)                SET BACK CHAIN FOR LINK TRACE
         B     MAINPROC                 DO MAINLINE PROCESSING
*                                  *----------------------------------*
*                                  *  EXIT PROCESSING                 *
*                                  *----------------------------------*
EXITPROC DS    0H
         L     13,4(,13)                RESTORE CALLER SAVEAREA
         ST    15,16(,13)               PASS RETURN CODE TO CALLER
         RETURN (14,12),T               RESTORE CALLER REGISTERS       +
                                                   AND RETURN TO CALLER
         EJECT ,
***********************************************************************
*        MAIN LINE PROCESSING.                                        *
*        =====================================================        *
*        GR1 -- EXEC PARAMETER PLIST                                  *
*        GR12 - BASE REGISTER                                         *
*        GR13 - OUR REGISTER SAVEAREA                                 *
*---------------------------------------------------------------------*
*        SAMPLE CODE OF 'MVS ADVANCED SKILL Vol-1' CHAPTER 5.3        *
*        =====================================================        *
*        PROGRAM CANCEL BY CPU TIMER EXPIRED.                         *
***********************************************************************
MAINPROC DS    0H
         STIMER TASK,TIMREXIT,          SET CPU INTERVAL TIMER         +
               BINTVL=INTRVAL
         SPACE ,
CPULOOP  DS    0H                       LOOP ON PURPOSE.
         L     R0,DOUBLE                  I
         LR    R1,R0                      I
         ST    R1,DOUBLE                  I
         B     CPULOOP                    V
         SPACE ,
*                                  *----------------------------------*
*                                  *  END OF PROCESSING               *
*                                  *----------------------------------*
         SLR   15,15                    LOAD RETURN CODE = 0
         B     EXITPROC                 DO EXIT PROCESSING
         SPACE ,
*                                  *----------------------------------*
*                                  *  ASYNCHRONOUS EXIT ROUTINE       *
*                                  *----------------------------------*
TIMREXIT DS    0H
         USING *,RF                     SET TEMP BASE
         STM   RE,RC,12(RD)             SAVE CALLER GPRS
         L     RC,AOURBASE              ESTABLISH OUR BASE REGISTER
         DROP  RF                       FORGET TEMP BASE
         WTO   'CPU TIME OVER...'       INFORM CPU TIME OVER...
         ABEND 322                                  AND ABEND WITH U322
AOURBASE DC    A(&MODNAME)              OUR BASE ADDRESS
         EJECT ,
***********************************************************************
*        DATA AREA                                                    *
***********************************************************************
         DS    0D
*---------------------------------------------------------------------*
DOUBLE   DC    D'0'                     DOUBLE WORD WORKAREA
INTRVAL  DC    F'1000'                  10.00 SECOND
*---------------------------------------------------------------------*
         LTORG ,                        LITERAL POOL AT HERE
         DROP  ,                        FORGET ALL BASE REGISTERS
         EJECT ,
***********************************************************************
*        DATA AREA (OUTSIDE OUR BASE)                                 *
***********************************************************************
*---------------------------------------------------------------------*
*        LOCAL WORKAREA                                               *
*---------------------------------------------------------------------*
*---------------------------------------------------------------------*
*        DSECTS                                                       *
*---------------------------------------------------------------------*
*---------------------------------------------------------------------*
*        S/370, ESA/390 REGISTER EQUATES                              *
*---------------------------------------------------------------------*
         YREGS ,                        OS: REGISTER EQUATES
RA       EQU   10                       ADD EQUATION FOR GR10
RB       EQU   11                       ADD EQUATION FOR GR11
RC       EQU   12                       ADD EQUATION FOR GR12
RD       EQU   13                       ADD EQUATION FOR GR13
RE       EQU   14                       ADD EQUATION FOR GR14
RF       EQU   15                       ADD EQUATION FOR GR15
         END
//
//